prg_dos_mod.F90

Go to the documentation of this file.

 
module prg_dos_mod
 
  use prg_openfiles_mod
  use prg_ptable_mod
 
  implicit none
 
  private
 
  integer, parameter :: dp = kind(1.0d0)
 
  public :: prg_write_tdos
 
contains
 
  subroutine prg_write_tdos(eigenvals, gamma, npts, emin, emax, filename)
    implicit none
    character(len=*),intent(in)       ::  filename
    integer                ::  i, io
    integer, intent(in)    ::  npts
    real(dp)               ::  de
    real(dp), allocatable  ::  loads(:)
    real(dp), intent(in)   ::  eigenvals(:), emax, emin, gamma
 
    call prg_open_file(io,filename)
 
    de = (emax-emin)/real(npts)
 
    allocate(loads(size(eigenvals)))
 
    loads = 1.0_dp
    write(io,*)"#  Energy    DOS"
    do i = 1, npts
      write(io,*) emin + de*i,lorentz(emin + de*i, eigenvals, loads, gamma)
    end do
 
    close(io)
 
    call prg_open_file(io, "eigenvals")
 
    write(io,*)"#  i   Eval"
    do i = 1, size(eigenvals,dim=1)
      write(io,*) i, eigenvals(i)
    end do
 
    close(io)
 
  end subroutine prg_write_tdos
 
 
  real(dp) function lorentz(energy, eigenvals, loads, gamma)
    implicit none
    integer               ::  nstates, k
    real(dp)              ::  auxfactor, auxterm, pi
    real(dp), intent(in)  ::  gamma, eigenvals(:), energy, loads(:)
 
    nstates = size(eigenvals,dim=1)
    pi = 3.14159265358979323846264338327950_dp
 
    !Lorentz parameters
    auxfactor = gamma/(2.0_dp*pi)
    auxterm = (gamma/2.0_dp)**2
    lorentz = 0.0_dp
 
    do k = 1, nstates
      lorentz = lorentz + loads(k)/((energy-eigenvals(k))**2 + auxterm)
    end do
 
    lorentz = auxfactor*lorentz
 
  end function lorentz
 
 
end module prg_dos_mod